Benutzer:ArchibaldWagner/MaterialWikidataUndPhysik

aus Wikipedia, der freien Enzyklopädie
Zur Navigation springen Zur Suche springen

Materialsammlung für Anwendungen von Wikidata im Bereich der Physik der Wikipedia


Material für Vortrag und Moderation[Bearbeiten | Quelltext bearbeiten]

Vorablinks[Bearbeiten | Quelltext bearbeiten]

Ziele[Bearbeiten | Quelltext bearbeiten]

  • Aufzeigen einiger Möglichkeiten der Nutzung von Wikidata
  • Beschluss: Zur Planung von ein bis zwei Anwendungen mit Wikidata-Elementen im Bereich Physik Redaktion

Ablauf Entwurf[Bearbeiten | Quelltext bearbeiten]

  • Kurze allgemeine Vorstellung (zur Erinnerung bzw. für die wenigen denen Wikidata bislang nichts sagt)
    • Projektziel
    • Status
    • Hinweise auf Links zur weiteren Information
  • Zugang für Wikidata-Editoren
    • Strukturierte Daten: Objekte Qnnn und Properties Pnnn
    • Wikidata Objekt (über die Artikelseite) (z.B. ein Physiker) (Erläuterung der Eigenschaften)
    • Editieren einer Eigenschaft/Relation
    • Historie
    • Einfügen von Belegen
  • Auffinden von Objekten (Beispiele) (ohne Erläuterung von SPARQL)
    • Physiker der Uni-Bonn
    • Physiker mit einem ausgezeichneten Wikipedia-Artikel
    • Physiker die heute Geburtstag haben und über die es einen Artikel in de.wiki gibt.
    • Forschungseinrichtungen (oder Kernreaktoren) in der Nähe von Berlin
  • Anwendungen in anderen Wiki-Projekten
    • Commons: 1,2 Beispiel aus Commons Projekte insb. Commons-Kategorien
    • Wikipedia: Infoboxen und Listen
  • Mögliche Anwendungen für das Physik-Portal und Nutzen für die Physik-Redaktion
    • Infoboxen (Naturwissenschaftler (Biografie), Forschungseinrichtungen, Chemische Elemente und Verbindungen)
    • Auf Physik-Portalseite: besondere dynamische Listen (mit Hilfe)
    • Kategorien (differentierte Abfragen, international einheitliche Kategorisierung)
  • Meinungsaustausch zu möglicher Nutzung und Anwendungsfälle im Bereich Physik
  • Konsensfindung, was wir in Zukunft angehen sollten.

Nutzung von Wikidata in Wikipedia[Bearbeiten | Quelltext bearbeiten]

Erste geeignete Infoboxen[Bearbeiten | Quelltext bearbeiten]

Problematische Daten in Wikidata[Bearbeiten | Quelltext bearbeiten]

Beispiel Abfragen[Bearbeiten | Quelltext bearbeiten]

#Most specific parent classes of Wikidata classes
# What is or are the lowest common ancestor(s) of a 
# church, a mosque, a synagogue and a palace in the 
# Wikidata ontology ? Answer : an architectural structure

SELECT ?lcs ?lcsLabel WHERE {
    ?lcs ^wdt:P279* wd:Q32815, wd:Q34627, wd:Q16970, wd:Q16560 .
    filter not exists {
    ?sublcs ^wdt:P279* wd:Q32815, wd:Q34627, wd:Q16970, wd:Q16560 ;
          wdt:P279 ?lcs . }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en" . }
  }

#Objekte mit Wikispecies-Interwikilinks
#added before 2016-10
#illustrates sitelink selection, ";" notation
SELECT ?item ?itemLabel ?article
WHERE
{
	?article 	schema:about ?item ;
			schema:isPartOf <https://species.wikimedia.org/> .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
LIMIT 200

#Ist ein thermodynamischer Prozess
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31 wd:Q213016.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 200

#Ist ein Experiment
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P279* wd:Q101965.     # ist ein Experiment
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 100

#"ist Teil von" "Physik"
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P361* wd:Q413.     # "ist Teil von" "Physik"
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 100

#"ist Teil von" "Maßeinheit"
SELECT ?item ?itemLabel ?unitLabel
WHERE 
{
  ?item wdt:P31 ?unit.     # "ist eine" "Einheit"
  ?unit wdt:P279 wd:Q47574.     # "ist Unterklasse von" "Maßeinheit"
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 200

#"ist eine " "SI-Einheit"
SELECT ?item ?itemLabel ?unitLabel
WHERE 
{
  ?item wdt:P31 ?unit.     # "ist eine" "abgeleitete SI-Einheit"
  ?unit wdt:P279* wd:Q61610698.     # "ist Unterklasse von" "SI-Einheit" !!!
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 200
#"ist eine" "SI-Einheit" mit einem Artikel in der deutschen Wikipedia
SELECT ?sitelink ?item ?itemLabel ?unitLabel
WHERE 
{
  ?item wdt:P31 ?unit.     # "ist eine" "abgeleitete SI-Einheit"
  ?unit wdt:P279* wd:Q61610698.     # "ist Unterklasse von" "SI-Einheit"
  ?sitelink schema:isPartOf <https://de.wikipedia.org/>;
     schema:about ?item. #;
     #wikibase:badge wd:Q17437796 . # Sitelink is badged as a Featured Article
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 200

#"ist Teil von " "CGS-Einheiten-System" mit einem Artikel in der deutschen Wikipedia
SELECT ?sitelink ?item ?itemLabel
WHERE 
{
  ?item wdt:P361 wd:Q26240.     # "ist Teil von" "abgeleitete CGS-Einheiten-System"
  ?sitelink schema:isPartOf <https://de.wikipedia.org/>;
     schema:about ?item. #;
     #wikibase:badge wd:Q17437796 . # Sitelink is badged as a Featured Article
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 200

Die folgende Abfrage führt zu Problemen, z.B. wird eine Archäologiche Periode als Zeiteinheit angegeben
<pre>
#ist *Unterklasse von Physikalische Größe
SELECT ?sitelink ?item ?itemLabel
WHERE 
{
  ?item wdt:P31 ?uclass.     # "ist Teil von" "abgeleitete CGS-Einheiten-System"
  ?uclass wdt:P279* wd:Q107715.  # ist Unterklasse von Physikalische Größe
  ?sitelink schema:isPartOf <https://de.wikipedia.org/>;
     schema:about ?item. #;
     #wikibase:badge wd:Q17437796 . # Sitelink is badged as a Featured Article
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 200
#"ist Unterklasse von Physikalische Größe
SELECT ?uclass ?uclassLabel
WHERE 
{
  #?item wdt:P31 ?uclass.     # ist Unterklasse von Physikalische Größe
  ?uclass wdt:P279 wd:Q107715.  # ist Unterklasse von Physikalische Größe
  #?sitelink schema:isPartOf <https://de.wikipedia.org/>;
  #   schema:about ?item. #;
     #wikibase:badge wd:Q17437796 . # Sitelink is badged as a Featured Article
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 200


Abfragen nach Physiker[Bearbeiten | Quelltext bearbeiten]


In wikipedia etwa 5 Millionen Q5 (Biografie Objekte)
In wikidata etwa 20000 Physiker        (2019-08-25)



#Frage nach Physikern, mit einem Artikel in de.wikipedia
#
#SELECT ( COUNT(?item) as ?numberOfPhysicists ) # result 7790 at 2019-08-25 time 51s
#
SELECT DISTINCT ?item ?itemLabel ?sitelink ?familiennameLabel ?vornameLabel
WHERE 
{
  ?item ( wdt:P106/wdt:P279* ) wd:Q169470.        # Tätigkeit '?classPhys', mit "property path" S 62-65
  ?sitelink schema:isPartOf <https://de.wikipedia.org/>;
            schema:about ?item.
#           wikibase:badge wd:Q17437796 . # Sitelink is badged as a Featured Article # Bedingung "is featured article" in de.wiki
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel 
LIMIT 10000



#Frage nach Physikern, mit einem Artikel in de.wikipedia
#
#SELECT ( COUNT(?item) as ?numberOfPhysicists ) # result 3430 at 2019-08-25 time 51s
#
SELECT DISTINCT ?item ?itemLabel ?sitelink ?familiennameLabel 
WHERE 
{
  ?item ( wdt:P106/wdt:P279* ) wd:Q169470;        # Tätigkeit '?classPhys', mit "property path" S 62-65
        wdt:P734 ?familienname;
        wdt:P735 ?vorname.                       
  ?sitelink schema:isPartOf <https://de.wikipedia.org/>;
            schema:about ?item.
#           wikibase:badge wd:Q17437796 . # Sitelink is badged as a Featured Article # Bedingung "is featured article" in de.wiki
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?familiennameLabel ?vornameLabel 
LIMIT 10000



# Frage nach Physiker, die heute Geburtstag haben - (braucht etwas mehr als 26s  Zeitprobleme ?)
# 
#SELECT ( COUNT(?item) as ?numberOfPhysicists ) # result 8842 at 2019-08-24
#
SELECT DISTINCT ?item ?itemLabel ?sitelink (YEAR(?date) as ?year) ?date 
WHERE 
{
  BIND(MONTH(NOW()) AS ?nowMonth)
  BIND(DAY(NOW()) AS ?nowDay)
  ?item wdt:P106/wdt:P279* wd:Q169470.        # Tätigkeit '?classPhys', mit "property path" S 62-65
  ?sitelink schema:isPartOf <https://de.wikipedia.org/>;
     schema:about ?item. #. ;
  ?site2link schema:isPartOf <https://en.wikipedia.org/>;
     schema:about ?item. #. ;
     #wikibase:badge wd:Q17437796 . # Sitelink is badged as a Featured Article  # 11 Artikel 2019-08-15
  ?item wdt:P569 ?date .
  FILTER (MONTH(?date) = ?nowMonth && DAY(?date) = ?nowDay)
# FILTER (MONTH(?date) = 1 && DAY(?date) = 2 ) #Rudolf Clausius
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 100



   SELECT DISTINCT ?item ?itemLabel WHERE {
         BIND(MONTH(NOW()) AS ?nowMonth)
         BIND(DAY(NOW()) AS ?nowDay)
         ?item wdt:P106/wdt:P279* wd:Q169470.        # Tätigkeit 'Physiker' 
         ?sitelink schema:isPartOf <https://de.wikipedia.org/>;  # there is an entry in de.wiki
            schema:about ?item. 
         ?site2link schema:isPartOf <https://en.wikipedia.org/>;  # there is an entry in de.wiki
            schema:about ?item. 
         ?item wdt:P569 ?date .
         FILTER (MONTH(?date) = ?nowMonth && DAY(?date) = ?nowDay)
         #FILTER (MONTH(?date) = 1 && DAY(?date) = 2 )
         SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
      } ORDER BY ?itemLabel



## Frage nach Physiker, die eine Seite auf de.wiki und en.wiki haben, und ordne 
# das Datum nach dem Geburtstag im Jahr
# 
#SELECT ( COUNT(?item) as ?numberOfPhysicists ) # result 4977 at 2019-08-26
#
SELECT DISTINCT ?item ?itemLabel ?sitelink (YEAR(?date) as ?year) ?date 
WHERE 
{
  ?item wdt:P106/wdt:P279* wd:Q169470.        # Tätigkeit '?classPhys', mit "property path" S 62-65
  ?sitelink schema:isPartOf <https://de.wikipedia.org/>;
     schema:about ?item. #. ;
  ?site2link schema:isPartOf <https://en.wikipedia.org/>;
     schema:about ?item. #. ;
  ?item wdt:P569 ?date .
  BIND( 100*MONTH(?date) + DAY(?date) AS ?monthday )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?monthday 



## Frage nach Physiker, die eine Seite auf de.wiki und en.wiki haben, und ordne 
# das Datum nach dem Geburtstag im Jahr
# 
#SELECT ( COUNT(?item) as ?numberOfPhysicists ) # result 1721 at 2019-08-26
#
SELECT DISTINCT ?item ?itemLabel ?sitelink (YEAR(?date) as ?year) ?date 
WHERE 
{
  ?item wdt:P106/wdt:P279* wd:Q169470.        # Tätigkeit '?classPhys', mit "property path" S 62-65
  ?sitelink schema:isPartOf <https://de.wikipedia.org/>;
     schema:about ?item. #. ;
  ?site2link schema:isPartOf <https://en.wikipedia.org/>;
     schema:about ?item. #. ;
  ?item wdt:P569 ?date .
#  ?item wdt:P166/wdt:P31? wd:Q38104 . # physics nobel laureat
#  ?item wdt:P166/wdt:P31? wd:Q7191 . # nobel laureat
  BIND( 100*MONTH(?date) + DAY(?date) AS ?monthday )
  FILTER( YEAR(?date) < 1900 ) .  # <====
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?monthday 



#Frage nach Physiker, mit einem Artikel in de.wikipedia
# und Arbeitgeber war die Uni Bonn  (71 Leute 2019-08-15)
#
#SELECT ( COUNT(?item) as ?numberOfPhysicists ) # result 8842 at 2019-08-24
#
SELECT ?item ?itemLabel ?classPhysLabel ?sitelink
WHERE 
{
  ?item wdt:P106/wdt:P279* wd:Q169470;   # Tätigkeit '?classPhys'
        wdt:P108 wd:Q152171.             # Arbeitgeber 'Uni Bonn'
  ?sitelink schema:isPartOf <https://de.wikipedia.org/>;
            schema:about ?item. #. ;
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 500



#Frage nach Physiker, mit einem 'ausgezeichneten' Artikel in de.wikipedia 
#
# SELECT ( COUNT(?item) as ?numberOfPhysicists ) # result 12 at 2019-08-25
#
SELECT DISTINCT ?item ?itemLabel ?sitelink
WHERE 
{
  ?item wdt:P106/wdt:P279* wd:Q169470.
  ?sitelink schema:isPartOf <https://de.wikipedia.org/>;
     schema:about ?item; 
     wikibase:badge wd:Q17437796 . # Sitelink is badged as a Featured Article  # 12 Artikel 2019-08-15
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 200



Abfrage nach Forschungseinrichtungen[Bearbeiten | Quelltext bearbeiten]


# Items ist eine Forschungseinrichtung in Deutschland
#
# SELECT ( COUNT(?item) as ?numberOfResearchInstituts ) # result 720 at 2019-08-22
#
SELECT ?item ?itemLabel ?organisationLabel
WHERE 
{
  ?item wdt:P31 wd:Q31855;   # ist eine Forschungseinrichtung
        wdt:P17 wd:Q183.     # Staat  Deutschland
  OPTIONAL { ?item wdt:P463 ?organisation. } # is member of organisation
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 1000



# Item ist eine Forschungseinrichtung in Deutschland, Schweiz oder Österreich
#
# SELECT ( COUNT(?item) as ?numberOfResearchInstituts ) # result 927 at 2019-08-23
#
SELECT ?item ?itemLabel ?fieldOfWorkLabel ?organisationLabel ?countryLabel
WHERE 
{
  ?item wdt:P31 wd:Q31855;   # ist eine Forschungseinrichtung
        wdt:P17 ?country.
  { ?item wdt:P17 wd:Q183 . } # Deutschland
  UNION
  { ?item wdt:P17 wd:Q39 . } # Schweiz
  UNION
  { ?item wdt:P17 wd:Q40 . } # Österreich
  OPTIONAL { ?item wdt:P463 ?organisation } # Mitglied Organisation
  OPTIONAL { ?item wdt:P101 ?fieldOfWork } # Arbeitsgebiet
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?countryLabel ?itemLabel
LIMIT 1000



Abfrage nach Kernreaktor[Bearbeiten | Quelltext bearbeiten]


# Items ist ein Kernreaktor
#
# SELECT ( COUNT(?item) as ?numberOfResearchInstituts ) # result 349 at 2019-08-23
#
SELECT ?item ?itemLabel ?countryLabel
WHERE 
{
  ?item wdt:P31 wd:Q134447.   # ist ein Kernreaktor
  OPTIONAL { ?item wdt:P17 ?country. } # is member of organisation
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?countryLabel ?itemLabel
LIMIT 1000



Für die Abfrage nach Forschungsreaktor fehlen die meisten Daten in Wikidata (meist einfach nur Bauwerk und Staat ohne Hinweis auf Forschung etc. (2019-08-23)



Abfrage nach Klassen[Bearbeiten | Quelltext bearbeiten]


#Frage nach Unterklassen 
#  (18 Stück, ohne '*' 14 Stück)
#SELECT ( COUNT(?item) as ?numberOfPhysicists ) # result 7184 at 2019-08-15
#
SELECT ?classLabel ?class
WHERE 
{
  ?class wdt:P279* wd:Q169470.   # Unterklasse der Klasse 'Physiker'
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 100



#Frage nach Unterklassen 'Experiment'
#  
# SELECT ( COUNT(?class) as ?numberOfSubClasses ) # result 130 at 2019-08-16
#
SELECT ?classLabel ?class
WHERE 
{
  ?class wdt:P279* wd:Q101965.   # Unterklasse der Klasse 'Experiment'
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 500



Experimentalphysik hat keine Unterklassen



#Frage nach Unterklassen von 'Physikalische Größe'
#  
#SELECT ( COUNT(?class) as ?numberOfSubClasses ) # result 7426 at 2019-08-16
#
SELECT ?classLabel ?class ?upperclassLabel ?upperclass
WHERE 
{
  ?class wdt:P279* wd:Q107715;   # Unterklasse der Klasse 'Physikalische Größe'
         wdt:P279 ?upperclass.   # direkte Oberklasse bestimmen
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
#GROUP BY ?upperclass
#ORDER BY ?upperclass
ORDER BY ?classLabel
LIMIT 8000



Mit über 7000 Einträgen enthält diese Suche viele unsinnige Einträge, insbesondere Abstand und Zeiteinheit scheinen viele nicht physikalische Objekte zu bringen, aber auch "wind engeneering" ist eine Unterklasse von Kraft



Abfrage nach Properties[Bearbeiten | Quelltext bearbeiten]


#Frage nach Eigenschaften - Wikidata-Eigenschaft für physikalische Größen
#  
#SELECT ( COUNT(?item) as ?numberOfProperties ) # result 125 at 2019-08-16
#
SELECT ?item ?itemLabel
WHERE 
{
  ?item wdt:P31 wd:Q21077852.   # is eine Wikidata Eigenschaft für eine Phys. Größe
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 1000



hier fehlen einige Material-Größen, wie etwa Schmelzenthalpie

Items mit Dichteangabe

Zur Abfragetechnik siehe WIKIDATA_Precision,_Units_and_Coordinates



#Frage nach Objekten mit einer Dichteangabe
#  
#SELECT ( COUNT(?item) as ?numberOfProperties ) # result 1175 Werte at 2019-08-16
#
SELECT ?item ?itemLabel ?unit ?unitLabel ?density 
WHERE 
{
  #?prop wdt:P31 wd:Q21077852.   # ist ein Wikidata Property Physikalische Größe
  ?item          p:P2054                     ?stmnode.    
  ?stmnode       psv:P2054                   ?valuenode.
  ?valuenode     wikibase:quantityAmount     ?density.
  ?valuenode     wikibase:quantityUnit       ?unit.
  #BIND((?upperbound-?lowerbound)/2 AS ?precision).
  #BIND(IF(?precision=0, ?length, (CONCAT(str(?length), "±", str(?precision)))) AS ?length2). 
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 2000



#Frage nach Objekten mit einem Massewert
#  
#SELECT ( COUNT(?item) as ?numberOfProperties ) # result 297346 Werte at 2019-08-16
#
SELECT ?item ?itemLabel ?unit ?unitLabel ?mass 
WHERE 
{
  #?prop wdt:P31 wd:Q21077852.   # ist ein Wikidata Property Physikalische Größe
  ?item          p:P2067                     ?stmnode.    
  ?stmnode       psv:P2067                   ?valuenode.
  ?valuenode     wikibase:quantityAmount     ?mass.
  ?valuenode     wikibase:quantityUnit       ?unit.
  #BIND((?upperbound-?lowerbound)/2 AS ?precision).
  #BIND(IF(?precision=0, ?length, (CONCAT(str(?length), "±", str(?precision)))) AS ?length2). 
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
#ORDER BY ?itemLabel
LIMIT 500



hier werden auch viele Menschen mit einem Gewicht von 75kg erwähnt.

Jetzt nur auf Werte in einer atomaren Masseneinheit



#Frage nach Objekten mit einem Massewert mit einer atomaren Masseneinheit
#  
#SELECT ( COUNT(?item) as ?numberOfProperties ) # result 150790 Werte at 2019-08-16
#
SELECT ?item ?itemLabel ?mass 
WHERE 
{
  #?prop wdt:P31 wd:Q21077852.   # ist ein Wikidata Property Physikalische Größe
  ?item          p:P2067                     ?stmnode.    
  ?stmnode       psv:P2067                   ?valuenode.
  ?valuenode     wikibase:quantityAmount     ?mass.
  ?valuenode     wikibase:quantityUnit       wd:Q483261.  # unit ist eine atomare Masseneinheit
  #BIND((?upperbound-?lowerbound)/2 AS ?precision).
  #BIND(IF(?precision=0, ?length, (CONCAT(str(?length), "±", str(?precision)))) AS ?length2). 
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 500



Abfragen nach Fachgebieten[Bearbeiten | Quelltext bearbeiten]



#Frage nach Fachgebiet die ein (ist ein) 'Teilgebiet der Physik' sind
#  
#SELECT ( COUNT(?item) as ?numberOfProperties ) # result 172 Fachgebiete at 2019-08-16
#
SELECT ?item ?itemLabel ?upperdivision ?upperdivisionLabel
WHERE 
{
  ?item wdt:P31* wd:Q4162444;   # ist ein 'Teilgebiet von Physik'
        wdt:P31 ?upperdivision.   # gehört zur Obermenge
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 500



Abfrage nach Klassen von Maßeinheiten[Bearbeiten | Quelltext bearbeiten]


#Abfrage nach *Unterklasse beliebiger Tiefe (hier von Maßeinheit)
# allein 134 Währungseinheiten
# und 352 andere Einheiten
# SELECT ( COUNT(?item) as ?numberOfItems ) # 5277 items
SELECT ?item ?itemLabel ?superclass ?superclassLabel
WHERE 
{
  ?item wdt:P279* wd:Q47574.  # ist Unterklasse von SI UNIT
  ?item wdt:P279 ?superclass.  # ist Unterklasse von Physikalische Größe
  FILTER NOT EXISTS { ?item wdt:P279* wd:Q8142 } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 1000



Ist Teil von Abfragen[Bearbeiten | Quelltext bearbeiten]


#Frage nach Objekten die "ein Teil von" 'Thermodynamik' sind
#  
#SELECT ( COUNT(?item) as ?numberOfProperties ) # result 10 Fachgebiete at 2019-08-16
#
SELECT ?item ?itemLabel ?upperdivision ?upperdivisionLabel
WHERE 
{
  ?item wdt:P361* wd:Q11473;   # ist ein Teil von 'Thermodynamik'
        wdt:P361 ?upperdivision.   # gehört zur Obermenge
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 500



liefert nur 10 Ergebnisse



#Frage nach Objekten die "ein Teil von" 'Physik' sind
#  
#SELECT ( COUNT(?item) as ?numberOfProperties ) # result 159 Fachgebiete at 2019-08-16
#
SELECT ?item ?itemLabel ?upperdivision ?upperdivisionLabel
WHERE 
{
  ?item wdt:P361* wd:Q413;   # ist ein Teil von 'Physik'
        wdt:P361 ?upperdivision.   # gehört zur Obermenge
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 500



Abfragen nach Relationsstrukturen[Bearbeiten | Quelltext bearbeiten]


#Abfrage nach *Unterklasse beliebiger Tiefe (hier von Physikalische Größe)
SELECT ( COUNT(?item) as ?numberOfItems ) # 5277 items
# SELECT ?item ?itemLabel
WHERE 
{
  ?item wdt:P279* wd:Q107715.  # ist Unterklasse von Physikalische Größe
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 1000



#Abfrage nach *Unterklasse 1. 2. Ebene
# SELECT ( COUNT(?item) as ?numberOfItems ) # 413 items
SELECT ?item ?itemLabel
WHERE 
{
  ?item ( wdt:P279 | wdt:P279/wdt:P279 ) wd:Q107715.  # ist Unterklasse von Physikalische Größe
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
LIMIT 1000



Stichworte[Bearbeiten | Quelltext bearbeiten]


Ideen für Listen und Tabellen - Nutze Personen Info

Mitarbeiter eines bestimmten Instituts

Physiker die in einem bestimmten Zeitraum geboren wurden 

-- 

Infoboxen zu chemischen Elementen ?

--

Kategorien?

--



  • Globale Daten die nur einmal gepflegt werden müssen. (Hierzu Frage der Pflege, der Versionierung und der Belege)

    • Personendaten
      • 

    • Materialdaten
      • 

    • Geografische- und astronomische Daten
      • 

    • Organisationen
    • 

  • Abfragen mit komplexen Bedingungen


Welche Properties wären für die Physik interessant
Gibt es Wikidata-Abfragen für die Wartung und Pflege,
Konsistens mit anderen Sprachen, en, es, fr









Abgerufen von „https://de.wikipedia.org/w/index.php?title=Benutzer:ArchibaldWagner/MaterialWikidataUndPhysik&oldid=192042463“